Официалният форум на iPlay.bg 

Очакваме вашите мнения за бъдещето на iPlay.bg тук (IPLAY.BG - ЩЕ НИ БЪДЕ ЛИ?).
Искате ли да сменим темата на форума? Можете да се изкажете тук (ПРЕДЛОЖЕНИЯ ЗА НОВ СТИЛ/ТЕМА НА ФОРУМА).
Списък с по-често ползваните функции, обяснения и примери за същите.
 #391565  от OciXCrom™
 нед май 29, 2016 11:05 pm
set_user_noclip(id, noclip = 0)

index: ID-то на играча
noclip: 1 е включено; 0 = изключено.

Връща: нищо Функцията служи за да направите играча способен да минава през стени, т.е. да активирате noclip.

Примерен плъгин №1: Активиране на noclip чрез използване на командата /noclip.
Код: Избери всички
#include <amxmodx>
#include <fun>

#define PLUGIN_NAME "Activate Noclip"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "iPlay.bg (OciXCrom)"

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
    register_clcmd("say /noclip", "cmdNoclip")
    register_clcmd("say_team /noclip", "cmdNoclip")
}

public cmdNoclip(id)
{
    set_user_noclip(id, 1)
    client_print(id, print_chat, "* Uspeshno aktivira noclip!")
    return PLUGIN_HANDLED
} 
Примерен плъгин №2: Автоматизирано включване и изключване на noclip чрез използване на командата /noclip.
Код: Избери всички
#include <amxmodx>
#include <fun>

#define PLUGIN_NAME "Toggle Noclip"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "iPlay.bg (OciXCrom)"

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
    register_clcmd("say /noclip", "cmdNoclip")
    register_clcmd("say_team /noclip", "cmdNoclip")
}

public cmdNoclip(id)
{
    new bool:blNoclip = get_user_noclip(id) ? true : false
    set_user_noclip(id, blNoclip ? 0 : 1)
    client_print(id, print_chat, "* Noclip rejimut e: %s", blNoclip ? "IZKLIUCHEN" : "VKLIUCHEN")
    return PLUGIN_HANDLED
} 
Примерен плъгин №3: Автоматично включване на noclip за всички играчи и изключване чрез използване на командите /noclip on и /noclip off.
Код: Избери всички
#include <amxmodx>
#include <fun>

#define PLUGIN_NAME "Toggle Noclip for All"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "iPlay.bg (OciXCrom)"

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
    register_clcmd("say", "hookSay")
    register_clcmd("say_team", "hookSay")
}

public hookSay(id)
{
    new szSay[11], szCommand[7], szArg[3]
    read_args(szSay, charsmax(szSay))
    remove_quotes(szSay)
    
    parse(szSay, szCommand, charsmax(szCommand), szArg, charsmax(szArg))
    
    if(!equal(szCommand, "/noclip"))
        return PLUGIN_CONTINUE
        
    new iSetting = szArg[1] == 'n' ? 1 : 0
    
    new iPlayers[32], iPnum
    get_players(iPlayers, iPnum, "a")
    
    for(new i; i < iPnum; i++)
        set_user_noclip(iPlayers[i], iSetting)
    
    client_print(id, print_chat, "* Noclip rejimut e: %s", iSetting ? "VKLIUCHEN" : "IZKLIUCHEN")
    return PLUGIN_HANDLED
}