Официалният форум на iPlay.bg 

Очакваме вашите мнения за бъдещето на iPlay.bg тук (IPLAY.BG - ЩЕ НИ БЪДЕ ЛИ?).
Искате ли да сменим темата на форума? Можете да се изкажете тук (ПРЕДЛОЖЕНИЯ ЗА НОВ СТИЛ/ТЕМА НА ФОРУМА).
Искате да ви намерим определен плъгин, или пък да ви изработим такъв? Пишете тук!
 #408542  от Donald :]]
 вт яну 24, 2017 5:51 pm
Здравейте, трябвами sniper плъгин .. когато в чата, играчите с флаг "t" напишат /snipers да излиза меню от което да избират между тези два снайпера "G3SG1" и "SG552" ( и двата снайпера да струват 10000$) когато си закупят един от двата снайпера да има дава и deagle. Също така и когато си купят снайпер да се запазват и другите им оръжия.
 #408547  от OciXCrom™
 вт яну 24, 2017 7:52 pm
Код: Избери всички
#include <amxmodx>
#include <cstrike>
#include <fun>

#define SHOP_ACCESS ADMIN_LEVEL_H

enum _:Items
{
    Name[32],
    Price,
    Weapon[16],
    WeaponId,
    Ammo
}

new const g_eItems[][Items] =
{
    { "G3SG1", 10000, "weapon_g3sg1", CSW_G3SG1, 90 },
    { "SG552", 10000, "weapon_sg552", CSW_SG552, 90 }
}

new g_iSayText
new const g_szPrefix[] = "!g[Snipers Shop]!n"

public plugin_init()
{
    register_plugin("Snipers Shop", "1.0", "OciXCrom @ forum.iPlay.bg")
    register_clcmd("say /snipers", "SnipersMenu")
    register_clcmd("say_team /snipers", "SnipersMenu")
    g_iSayText = get_user_msgid("SayText")
}

public SnipersMenu(id)
{
    if(get_user_flags(id) & SHOP_ACCESS)
    {
        new iMenu = menu_create("Izberi sniper", "SnipersMenu_Handler")
        
        for(new szItem[64], iMoney = cs_get_user_money(id), i; i < sizeof(g_eItems); i++)
        {
            formatex(szItem, charsmax(szItem), "%s %s[%i$]", g_eItems[i][Name], iMoney >= g_eItems[i][Price] ? "\r" : "\d", g_eItems[i][Price])
            menu_additem(iMenu, szItem)
        }
        
        menu_display(id, iMenu, 0)
    }
    else
        ColorChat(id, "Nqmash dostup do tazi komanda.")
    
    return PLUGIN_HANDLED
}

public SnipersMenu_Handler(id, iMenu, iItem)
{
    if(iItem != MENU_EXIT && is_user_alive(id))
    {
        new iMoney = cs_get_user_money(id)
        
        if(iMoney < g_eItems[iItem][Price])
            ColorChat(id, "Nqmash dostatuchno pari za da zakupish tova orujie!")
        else
        {
            give_item(id, g_eItems[iItem][Weapon])
            cs_set_user_bpammo(id, g_eItems[iItem][WeaponId], g_eItems[iItem][Ammo])
            cs_set_user_money(id, iMoney - g_eItems[iItem][Price])
            ColorChat(id, "Zakupi !t%s !nza !g%i$", g_eItems[iItem][Name], g_eItems[iItem][Price])
            
            give_item(id, "weapon_deagle")
            cs_set_user_bpammo(id, CSW_DEAGLE, 35)
        }
    }
    
    menu_destroy(iMenu)
    return PLUGIN_HANDLED
}
            
ColorChat(const id, const szInput[], any:...)
{
    new iPlayers[32], iCount = 1
    static szMessage[191]
    vformat(szMessage, charsmax(szMessage), szInput, 3)
    format(szMessage[0], charsmax(szMessage), "%s %s", g_szPrefix, szMessage)
    
    replace_all(szMessage, charsmax(szMessage), "!g", "^4")
    replace_all(szMessage, charsmax(szMessage), "!n", "^1")
    replace_all(szMessage, charsmax(szMessage), "!t", "^3")
    
    if(id)
        iPlayers[0] = id
    else
        get_players(iPlayers, iCount, "ch")
    
    for(new i; i < iCount; i++)
    {
        if(is_user_connected(iPlayers[i]))
        {
            message_begin(MSG_ONE_UNRELIABLE, g_iSayText, _, iPlayers[i])
            write_byte(iPlayers[i])
            write_string(szMessage)
            message_end()
        }
    }
} 
 #408553  от OciXCrom™
 вт яну 24, 2017 8:22 pm
Като прочетеш уроци как се компилира плъгин. Имаш сървър, а не знаеш как се добавя плъгин. Интересно.
 #408554  от Donald :]]
 вт яну 24, 2017 8:24 pm
Благодаря. И никой не е казал че имам сървър... Може да я заключваш
 #408555  от OciXCrom™
 вт яну 24, 2017 8:27 pm
Мда, то забравих, че плъгините може да се ползват и ако нямаш сървър. :whistle: