Официалният форум на iPlay.bg 

  • Admin spec

  • Искате да ви намерим определен плъгин, или пък да ви изработим такъв? Пишете тук!
Искате да ви намерим определен плъгин, или пък да ви изработим такъв? Пишете тук!
 #401655  от PuBL!c
 ср ное 09, 2016 11:03 am
Здравейте, отново. <3 :D

Желая плъгин, за администратори със права за бан, като напишат в чата: /aspec да ги праща директно към спекакторите. И да им дава определен модел/скин.

:ps: Ползвам плъгина за модели на TheRedShoko, ще има ли бъгове?
 #401663  от OciXCrom™
 ср ное 09, 2016 12:03 pm
Код: Избери всички
#include <amxmodx>
#include <cstrike>

#define PLUGIN_VERSION "1.0"
#define MODEL_NAME "imeto_na_skin_faila"
#define NEEDED_FLAG ADMIN_BAN

public plugin_init()
{
    register_plugin("Admin Spec", PLUGIN_VERSION, "OciXCrom")
    register_clcmd("say /aspec", "GoSpec")
    register_clcmd("say_team /aspec", "GoSpec")
}

public plugin_precache()
{
    new szModel[128]
    formatex(szModel, charsmax(szModel), "models/player/%s/%s.mdl", MODEL_NAME, MODEL_NAME)
    precache_model(szModel)
    
    replace(szModel, charsmax(szModel), ".mdl", "T.mdl")
    
    if(file_exists(szModel))
        precache_model(szModel)
}

public GoSpec(id)
{
    if(!(get_user_flags(id) & NEEDED_FLAG))
        client_print(id, print_chat, "* You have no access to this command.")
    else if(cs_get_user_team(id) == CS_TEAM_SPECTATOR)
        client_print(id, print_chat, "* You are already a spectator!")
    {
        cs_set_user_team(id, CS_TEAM_SPECTATOR)
        
        if(is_user_alive(id))
            cs_set_user_model(id, MODEL_NAME)
    }
    
    return PLUGIN_HANDLED
} 
 #401667  от PuBL!c
 ср ное 09, 2016 1:07 pm
EDIT: Ще те помоля, примерно когато е бил от еди си кой отбор и когато мине спектатор, да може като напише: /back да се върне в отбора, който е бил.
Изхвърля ме от сървъра, като изписва, че моделът не съществува, а модела е в models/player папката.
 #401671  от OciXCrom™
 ср ное 09, 2016 2:16 pm
Код: Избери всички
#include <amxmodx>
#include <cstrike>

#define PLUGIN_VERSION "1.0"
#define MODEL_NAME "imeto_na_skin_faila"
#define NEEDED_FLAG ADMIN_BAN

new CsTeams:g_iOldTeam[33]

public plugin_init()
{
    register_plugin("Admin Spec", PLUGIN_VERSION, "OciXCrom")
    register_clcmd("say /aspec", "GoSpec")
    register_clcmd("say_team /aspec", "GoSpec")
    register_clcmd("say /back", "GoBack")
    register_clcmd("say_team /back", "GoBack")
}

public plugin_precache()
{
    new szModel[128]
    formatex(szModel, charsmax(szModel), "models/player/%s/%s.mdl", MODEL_NAME, MODEL_NAME)
    precache_model(szModel)
    
    replace(szModel, charsmax(szModel), ".mdl", "T.mdl")
    
    if(file_exists(szModel))
        precache_model(szModel)
}

public GoSpec(id)
{
    if(!(get_user_flags(id) & NEEDED_FLAG))
        client_print(id, print_chat, "* You have no access to this command.")
    else if(cs_get_user_team(id) == CS_TEAM_SPECTATOR)
        client_print(id, print_chat, "* You are already a spectator!")
    else
    {
        g_iOldTeam[id] = cs_get_user_team(id)
        cs_set_user_team(id, CS_TEAM_SPECTATOR)
        
        if(is_user_alive(id))
            cs_set_user_model(id, MODEL_NAME)
    }
    
    return PLUGIN_HANDLED
}

public GoBack(id)
{
    if(!(get_user_flags(id) & NEEDED_FLAG))
        client_print(id, print_chat, "* You have no access to this command.")
    else if(cs_get_user_team(id) != CS_TEAM_SPECTATOR)
        client_print(id, print_chat, "* You are not a spectator!")
    else
    {
        cs_set_user_team(id, g_iOldTeam[id])
        
        if(is_user_alive(id))
            cs_reset_user_model(id)
    }
    
    return PLUGIN_HANDLED
} 
Снимка къде си добавил модела, където ясно се виждат останалите предишни папки, както и какво си написал в #define MODEL_NAME "imeto_na_skin_faila".
 #401674  от OciXCrom™
 ср ное 09, 2016 2:38 pm
Тествано и работи без проблеми. Мога да предположа, че папката "Jack" е празна или в нея си сложил още 3 такива папки. Темата се заключва.